100 REM Program 'ATOM101.BAS' introduces the user to basic atomic physics.
110 REM Worked examples are from COLLEGE PHYSICS, Serway & Faughn, 1992.  All
120 REM variables = double precision except I*.     R. B. Minton, 09/12/2004.
130 DEFDBL A-H: DEFDBL J-Z:                    REM I=SINGLE, REST=DOUBLE
140 DEF FNA(X)=INT(X*10+.5)/10:                REM ROUND TO 1 DECIMAL PLACE
150 DEF FNB(X)=INT(X*100+.5)/100:              REM ROUND TO 2 DECIMAL PLACES
160 DEF FNC(X)=INT(X*1000+.5)/1000:            REM ROUND TO 3 DECIMAL PLACES
170 DEF FND(X)=INT(X*10000+.5)/10000:          REM ROUND TO 4 DECIMAL PLACES
180 DEF FNE(X)=INT(X*100000!+.5)/100000!:      REM ROUND TO 5 DECIMAL PLACES
190 DEF FNF(X)=INT(X*1000000!+.5)/1000000!:    REM ROUND TO 6 DECIMAL PLACES
200 DEF FNG(X)=LOG(X)/(LOG(10#)):              REM LOG BASE 10(X)
210 DEF FNH(X)=LOG(X)/(LOG(E)):                REM LOG BASE E(X) [NATURAL LOG]
220 DEF FNJ(X)=X*C*C:                          REM ENERGY = MC^2 (JOULES)
230 DEF FNM(X)=X*C*C*6241455000000#:           REM ENERGY = MC^2 (MeV)
240 DEF FNY(X)=ATN(X/SQR(1#-(X*X))):           REM ASIN(X)
250 DEF FNZ(X)=ATN(SQR(1#-(X*X))/X):           REM ACOS(X)
260 DIM M$(25):                                REM 1 SCREEN OF INFO LINES
270 DIM F$(25):                                REM FORMATS AND PROMPTS
280 REM ----------- DEFINE SOME CONSTANTS AND CONVERSION FACTORS ------------
290 REM THE ARITHMETIC OVERFLOW VALUE BELOW RESULTS WITH A DIVISION BY ZERO !
300 AO=1.7014D+38:                         REM ARITHMETIC OVERFLOW VALUE
310 PI=4#*ATN(1#):                         REM PI=3.141592653589793
320 RAD=180#/PI:                           REM RADIAN=57.29577951308232
330 C=299792458#:                          REM SPEED OF LIGHT (M/SEC)
340 CC=29979245800#:                       REM SPEED OF LIGHT (CM/SEC)
350 MUO=1.256637061435917D-06:             REM PERMEABILITY OF FREE SPACE
360 EOH=8.841941282883074D-12:             REM PERMITTIVITY OF FREE SPACE
370 E=2.7182818459045#:                    REM VALUE OF E
380 NM=.000000001#:                        REM RATIO NANOMETER / METER
390 NRC=.0000000000000012#:                REM NUCLEAR RADIUS CONSTANT
400 EV=1.60217733D-19:                     REM ELECTRON VOLT, JOULES
410 EM=9.1093897D-31:                      REM ELECTRON MASS, KG
420 AMU=1.6605402D-27:                     REM ATOMIC MASS UNIT, KG
430 JKG=8.987551787368177D+16:             REM JOULES PER KILOGRAM
440 AN=6.0221367D+23:                      REM AVOGADRO'S NUMBER
450 COU=6.25D+18:                          REM COULOMB CONSTANT, N*M^2/C^2
460 PC=6.6260755D-34:                      REM PLANCK'S CONSTANT, J/SEC
470 BR=5.29177249D-11:                     REM BOHR RADIUS, METERS
480 BU$="       ":                         REM BLANKS TO CENTER SCREEN
490 FC$="       . . . . Enter <CR> to Continue "
500 FR$="       . . . . Enter R to Return, or <CR> to Continue "
510 FW$="       . . . . Enter Y to use Goto, or <CR> to Continue "
520 REM CONTINUE
530 KEY OFF: SCREEN 0,0,0: CLS
540 PRINT FW$;: INPUT CR$
550 IF CR$="Y" THEN GOTO 2820
560 REM CONTINUE
570 M$(1) ="------------------------------------------------------------------"
580 M$(2) ="                       Kinetic Energy                             "
590 M$(3) ="------------------------------------------------------------------"
600 M$(4) ="Moving objects posess a kinetic energy defined as KE = 1/2mv^2.   "
610 M$(5) ="The unit of work in the SI system of measurement is the Newton -  "
620 M$(6) ="meter or Joule; with mass measured in kg and velocity in meters/  "
630 M$(7) ="second.  The following example is from Astronomy, 10/04, p. 70-71."
640 M$(8) ="Asteroid Toutatis is approaching Earth at 35,000 km/hr, and it's  "
650 M$(9) ="maximum size is 4.5 x 2.4 km - what's the approx. kinetic energy? "
660 M$(10)="1)  No user input is required; but program makes some assumptions."
670 M$(11)="2)  Program computes mass w/ 3 densities: rock, iron, & 50% both. "
680 M$(12)="    (Rock = earth's crust = 2.64, iron = 7.86; and mean = 5.25).  "
690 M$(13)="3)  The width is much < 2.4 km in many places; program assumes the"
700 M$(14)="    total mass = 1/2 of a smooth surfaced 4.5 x 2.4 x 2.4 km body."
710 M$(15)="4)  Impact is claimed to be = 1 million megatons of TNT; calculate"
720 M$(16)="    approx. how many Joules are released by 1 ton & 1 g. of TNT.  "
730 M$(17)="------------------------------------------------------------------"
740 M$(18)="Intro to Space Science, Haymes, p. 119 states 1 ton of TNT = 4.2 x"
750 M$(19)="10^16 ergs.  (1 J = 10^7 ergs, 1 ton = 2240 lbs, and 1 lb. = 453.5"
760 M$(20)="9243 g.)  Thus 1 g. TNT = 4133.667 J.  The ratio of computed/exact"
770 M$(21)="Joules indicates that the true yield from this asteroid impact is "
780 M$(22)="probably much closer to 160,000 megatons of TNT - use REM'd yield!"
790 M$(23)="------------------------------------------------------------------"
800 FOR I=1 TO 17: PRINT BU$;: PRINT M$(I): NEXT I
810 PRINT FC$;: INPUT CR$: PRINT
820 F$(1)="##.####^^^^"
830 TNT=(4.2D+16/10000000#)/(2240*453.59243#):  REM TNT YIELD, J/g (HAYMES)
840 VEL=35000#/3600#:                      REM VELOCITY, KM/SEC
850 VEL=VEL*1000#:                         REM VELOCITY, M/SEC
860 H=4500#: W=2400#: VOL=(.5)*(H*W*W):    REM VOLUME, M^3
870 MR=(.45359243#)/2240#:                 REM MASS RATIO, KG PER TON
880 YIELD=(1000000#)*(1000000#):           REM YIELD=1 MILLION MEGA-TONS
890 REM YIELD=((1000000#*.16))*(1000000#):     REM BETTER FIT FOR YIELD
900 FOR I=1 TO 3
910   IF I=1 THEN MKG=2.64*1000#*VOL:T$=" rock": REM MASS (KG), TYPE
920   IF I=2 THEN MKG=7.86*1000#*VOL:T$=" iron": REM MASS (KG), TYPE
930   IF I=3 THEN MKG=5.25*1000#*VOL:T$=" both": REM MASS (KG), TYPE
940   KE=(.5)*MKG*(VEL*VEL):               REM KINETIC ENERGY, JOULES
950   IF I=3 THEN JRI=KE:                  REM JOULES (50% ROCK, 50% IRON)
960   PRINT BU$;:PRINT"If";:PRINT T$;:PRINT", approx. mass  (kg) =";
970   PRINT USING F$(1);MKG
980   PRINT BU$;:PRINT"                 energy (J) =";
990   PRINT USING F$(1);KE
1000   PRINT
1010 NEXT I
1020 PRINT BU$;:PRINT"(both = 50% rock and 50% iron by mass)"
1030 PRINT BU$;:PRINT"(computed # Joules below are for both)":PRINT
1040 RJ=JRI/YIELD:                          REM RATIO JOULES / # TONS TNT
1050 PRINT BU$;:PRINT"Computed # Joules/ton TNT   = ";:PRINT USING F$(1);RJ
1060 JG=RJ*MR*.001:                         REM JOULES PER GRAM TNT
1070 PRINT BU$;:PRINT"Computed # Joules/gram TNT  = ";:PRINT USING F$(1);JG
1080 PRINT BU$;:PRINT"Exact # Joules/gram TNT     = ";:PRINT USING F$(1);TNT
1090 FOR I=17 TO 23: PRINT BU$;: PRINT M$(I): NEXT I
1100 PRINT FC$;: INPUT CR$: CLS
1110 M$(1) ="------------------------------------------------------------------"
1120 M$(2) ="  Electromagnetic Radiation - Frequency, Wavelength, Wave Number  "
1130 M$(3) ="------------------------------------------------------------------"
1140 M$(4) ="Electromagnetic waves are transverse waves which CAN propogate    "
1150 M$(5) ="through a vacuum, and have electric and magnetic fields perpen-   "
1160 M$(6) ="dicular to the direction of wave travel.  The distance (Meters)   "
1170 M$(7) ="from 1 wave crest (or trough) to the next crest (or trough) is    "
1180 M$(8) ="the wavelength.  In a vacuum, e/m waves travel at the speed of    "
1190 M$(9) ="light (C).  The number of whole waves and any fractional wave     "
1200 M$(10)="passing a fixed point in 1 sec. is the frequency in Hertz (for-   "
1210 M$(11)="mally called cycles/sec).  Wave number (N here) is infrequently   "
1220 M$(12)="used, but is a reciprocal wavelength.  F=frequency, W=wavelength, "
1230 M$(13)="N=wave number, C=light, PI=pi.  F=C/W, W=C/F, N=2*PI/W, W=2*PI/N. "
1240 M$(14)="---------------------- Conversion factors ------------------------"
1250 M$(15)="1 Angstrom = 10^-10 meters & 6563.0 Angstroms = 6563.0D-10 meters "
1260 M$(16)="1 MHz      = 10^6   Hz     & 1420.4 MHz       = 1420.4D+06 Hz    "
1270 M$(17)="----------- Sample Conversions (units are for F W N) ------------"
1280 M$(18)="1420.4 MHz       = 1.4204D+09 Hz = 2.1106D-01 M = 3.0163D+00 M^-1"
1290 M$(19)="6563 Angstroms   = 4.5679D+14 Hz = 6.5630D-07 M = 9.7001D+05 M^-1"
1300 M$(20)="29.769 meters^-1 = 1.4204D+09 Hz = 2.1106D-01 M = 2.9769D+01 M^-1"
1310 M$(21)="----------------- Use UPPERCASE for response ! ------------------"
1320 FOR I=1 TO 21: M$(I)=BU$+M$(I): PRINT M$(I): NEXT I
1330 F$(1)="##.####^^^^"
1340 F$(2)="Enter 1 value & the other 2 will be computed . . .  "
1350 F$(3)="Input Frequency, Wavelength, or Wave number (FWN) : "
1360 F$(4)="Enter value.  Units are Hz, meters, or 1/meters   : "
1370 F$(5)="Invalid choice or lowercase.  Please use F, W, or N."
1380 F$(6)="Original value input: "
1390 F$(7)="Converted values are: "
1400 F$(8)="         1/2 wave is: "
1410 F$(9)="         1/4 wave is: "
1420 FOR I=2 TO 9: F$(I)=BU$+F$(I): NEXT I
1430 UF$=" Hz      ": UW$=" Meters   ": UN$=" Meters^-1": UI$=" Inches"
1440 REM CONTINUE
1450 PRINT F$(2): PRINT F$(3);: INPUT;TY$: PRINT
1460 PRINT F$(4);: INPUT V: PRINT
1470 REM
1480 IF TY$="F" THEN F=V: W=C/F: N=(2#*PI)/W: V$=" Hz       ": GOTO 1520
1490 IF TY$="W" THEN W=V: F=C/W: N=(2#*PI)/W: V$=" Meters   ": GOTO 1520
1500 IF TY$="N" THEN N=V: W=(2#*PI)/N: F=C/W: V$=" Meters^-1": GOTO 1520
1510 PRINT F$(5): PRINT FC$;: INPUT;CR$: GOTO 1440
1520 REM CONTINUE
1530 W2=W/2: W4=W/4: KI=39.37007874015748#: WI=W*KI: WI2=W2*KI: WI4=W4*KI
1540 PRINT F$(6);: PRINT V;: PRINT V$: PRINT
1550 PRINT F$(7);: PRINT USING F$(1);F;: PRINT UF$
1560 PRINT F$(7);: PRINT USING F$(1);W;: PRINT UW$;
1570 PRINT"= ";: PRINT USING F$(1);WI;: PRINT UI$
1580 PRINT F$(8);: PRINT USING F$(1);W2;: PRINT UW$;
1590 PRINT"= ";: PRINT USING F$(1);WI2;: PRINT UI$
1600 PRINT F$(9);: PRINT USING F$(1);W4;: PRINT UW$;
1610 PRINT"= ";: PRINT USING F$(1);WI4;: PRINT UI$
1620 PRINT F$(7);: PRINT USING F$(1);N;: PRINT UN$
1630 PRINT: PRINT FR$;: INPUT;CR$
1640 IF CR$="R" THEN GOTO 1440
1650 CLS
1660 REM
1670 M$(1) ="------------------------------------------------------------------"
1680 M$(2) =" Electromagnetic Radiation - Electric (E) and Magnetic (B) Fields "
1690 M$(3) ="------------------------------------------------------------------"
1700 M$(4) ="1: User inputs an electromagnetic (e/m) intensity in Watts.       "
1710 M$(5) ="2: User inputs the linear cross-section of this beam which has    "
1720 M$(6) ="   the given amount of e/m power.                                 "
1730 M$(7) ="3: (This energy can be light, radio waves, or any e/m radiation). "
1740 M$(8) ="4: Program computes the average power in Watts/square meter, and  "
1750 M$(9) ="   the electric and magnetic fields in Newtons/Coulomb and Teslas."
1760 M$(10)="5: The program assumes the e/m intensity is already in Watts, and "
1770 M$(11)="   there is 100% efficiency in generating the e/m intensity.      "
1780 M$(12)="6: The next section uses an omnidirectional light source, and the "
1790 M$(13)="   conversion efficiency can be entered IN THE BASIC SOURCE CODE. "
1800 M$(14)="------------------------------------------------------------------"
1810 M$(15)="                   Sample inputs & outputs:                       "
1820 M$(16)="Inputs:   power = 0.005 (light from a 5 mW laser pointer - the    "
1830 M$(17)="                         beam power is actually 5 milliwatts)     "
1840 M$(18)="          beam size = 0.005 (spot is 0.5 cm in dia. on wall)      "
1850 M$(19)="Outputs:  Watts per sq. meter = 2.5465 x 10+2 Watts/Meter^2       "
1860 M$(20)="          Magnetic field (B)  = 1.4611 x 10-6 Tesla               "
1870 M$(21)="          Electric field (Eo) = 4.3803 x 10+2 Newtons/Coulomb     "
1880 M$(22)="------------------------------------------------------------------"
1890 FOR I=1 TO 22: M$(I)=BU$+M$(I): PRINT M$(I): NEXT I: F1$="##.####^^^^"
1900 REM CONTINUE
1910 PRINT BU$;
1920 INPUT"Enter electromagnetic radiation power (Watts): ";WATTS: PRINT BU$;
1930 INPUT"Enter radiation's beam or spot size  (Meters): ";DIA: PRINT
1940 RSPOT=DIA/2: AREA=PI*(RSPOT*RSPOT): WPSM=WATTS/AREA
1950 B2=(WPSM*(2#*MUO))/C: B=SQR(B2): ELE=B*C
1960 F2$="Power per unit area           ="
1970 F3$="Magnetic field intensity  (B) ="
1980 F4$="Electric field intensity (Eo) ="
1990 PRINT BU$;:PRINT F2$;:PRINT USING F1$;WPSM;:PRINT" Watts/square meter"
2000 PRINT BU$;:PRINT F3$;:PRINT USING F1$;B;:PRINT" Tesla"
2010 PRINT BU$;:PRINT F4$;:PRINT USING F1$;ELE;:PRINT" Newtons/Coulomb"
2020 PRINT FR$;:INPUT;CR$
2030 IF CR$="R" THEN GOTO 1900
2040 CLS
2050 M$(1) ="------------------------------------------------------------------"
2060 M$(2) ="     Electromagnetic Radiation - Illumination at a Distance       "
2070 M$(3) ="------------------------------------------------------------------"
2080 M$(4) ="1: Program calculates the decrease in light intensity at a sur-   "
2090 M$(5) ="   face from an omnidirectional light source (a light bulb).      "
2100 M$(6) ="2: User is prompted for light bulb wattage and distance.          "
2110 M$(7) ="3: Program assumes ALL WATTAGE IS CONVERTED INTO LIGHT.  If not,  "
2120 M$(8) ="   enter the luminous efficiency INTO THE BASIC SOURCE CODE.      "
2130 M$(9) ="------------------------------------------------------------------"
2140 M$(10)="                   Sample inputs & outputs:                       "
2150 M$(11)="Inputs:   power = 15 Watts                                        "
2160 M$(12)="          distance = 1 Meter (distance of bulb to wall)           "
2170 M$(13)="Outputs:  Watts per sq. meter = 1.1937 x 10+0 Watts/Meter^2       "
2180 M$(14)="          Magnetic field (B)  = 1.0003 x 10-7 Tesla               "
2190 M$(15)="          Electric field (Eo) = 2.9990 x 10+1 Newtons/Coulomb     "
2200 M$(16)="------------------------------------------------------------------"
2210 FOR I=1 TO 16: M$(I)=BU$+M$(I): PRINT M$(I): NEXT I
2220 REM CONTINUE
2230 PRINT BU$;
2240 INPUT"Enter the light bulb wattage          (Watts): ";WATTS: PRINT BU$;
2250 REM LUME=.15: WATTS=WATTS*LUME:       REM BULB'S LUMINOUS EFFICIENCY=15%
2260 INPUT"Enter distance from bulb to surface  (Meters): ";DIS: PRINT
2270 TAREA=4#*PI*(DIS*DIS):                REM TOTAL AREA OF SPHERE AT DISTANCE
2280 WPSM=WATTS/TAREA:                     REM WATTS INCIDENT ON 1 SQ. METER
2290 B2=(WPSM*(2#*MUO))/C: B=SQR(B2): ELE=B*C
2300 F2$="Power per unit area           ="
2310 F3$="Magnetic field intensity  (B) ="
2320 F4$="Electric field intensity (Eo) ="
2330 PRINT BU$;:PRINT F2$;:PRINT USING F1$;WPSM;:PRINT" Watts/square meter"
2340 PRINT BU$;:PRINT F3$;:PRINT USING F1$;B;:PRINT" Tesla"
2350 PRINT BU$;:PRINT F4$;:PRINT USING F1$;ELE;:PRINT" Newtons/Coulomb"
2360 PRINT FR$;:INPUT;CR$
2370 IF CR$="R" THEN GOTO 2220
2380 CLS
2390 REM CONTINUE
2400 M$(1) ="------------------------------------------------------------------"
2410 M$(2) ="                         E = MC^2                                 "
2420 M$(3) ="------------------------------------------------------------------"
2430 M$(4) ="Einstein's famous mass-energy equivalence equation means energy is"
2440 M$(5) ="a form of mass, and mass is a form of energy.  Common endothermic "
2450 M$(6) ="and exothermic chemical reactions involve a gain or loss of mass! "
2460 M$(7) ="The relevance to man and the universe are unlimited.  3 examples  "
2470 M$(8) ="are shown below, the last is a chemical reaction showing the very "
2480 M$(9) ="miniscule energy release compared to atomic energy.               "
2490 M$(10)="1)  User specifies whether to compute energy (E) or mass (M).     "
2500 M$(11)="---------------------- Convert KG to Joules ----------------------"
2510 M$(12)="A baseball weighs 0.5 kg; calculate the equivalent energy in J.   "
2520 M$(13)="  E = MC^2 = (0.5 kg) x (3.0 x 10^8 m/sec) = 4.5 x 10^16 Joules   "
2530 M$(14)="---------------------- Convert Joules to KG ----------------------"
2540 M$(15)="The sun radiates 4x10^26 J/sec.; what is the kg/sec mass loss?    "
2550 M$(16)="  M = E/(C*C) = (4x10^26)/((3x10^8)*(3x10^8)) = 4.44 x 10^9 KG    "
2560 M$(17)="----- Convert J to KG & find ratio of atomic/chemical energy -----"
2570 M$(18)="1 g of H burns with 8 g of O forming 9 g of H2O and 2.86x10^5 J.  "
2580 M$(19)="What is the mass loss & energy ratio of Atomic vs. Chemical (A/C)?"
2590 M$(20)="M = E/C*C = 2.86D+5/(3D*8^2) = 3.18D-12 kg.  1 g. is equivalent to"
2600 M$(21)="0.001*C^2 = 8.99D+13 J.  A/C ratio = 8.99D+13/3.18D-12 = 2.83D+25."
2610 M$(22)="------------------- Use UPPERCASE for response -------------------"
2620 FOR I=1 TO 22: M$(I)=BU$+M$(I): PRINT M$(I): NEXT I
2630 PRINT FC$;: INPUT CR$
2640 F$(1)="##.####^^^^"
2650 F$(2)="Input error-check input-use uppercase-try again ! ! "
2660 F$(3)="                                                    "
2670 F$(4)="Calculate Energy (E), or Mass (M) equivalence     : "
2680 F$(5)="Enter the energy in Joules                        : "
2690 F$(6)="Enter the mass in kilograms                       : "
2700 F$(7)="The energy equivalence for this mass is exactly"
2710 F$(8)="The mass equivalence for this energy is exactly"
2720 FOR I=2 TO 8: F$(I)=BU$+F$(I): NEXT I
2730 UE$=" Joules": UM$=" kg"
2740 REM CONTINUE
2750 T=0: PRINT F$(4);: INPUT;TEM$
2760 IF TEM$="E" THEN T=1: PRINT F$(6);: INPUT;MX: EX=MX*(C*C)
2770 IF TEM$="M" THEN T=2: PRINT F$(5);: INPUT;EX: MX=EX/(C*C)
2780 IF T=1 THEN PRINT F$(7);: PRINT EX$;: PRINT USING F$(1);EX;: PRINT UE$
2790 IF T=2 THEN PRINT F$(8);: PRINT EX$;: PRINT USING F$(1);MX;: PRINT UM$
2800 PRINT: PRINT FR$;: INPUT;CR$: IF CR$="R" THEN GOTO 2740
2810 CLS
2820 REM CONTINUE
2830 REM ----------------------------------------------------------------
2840 REM PROGRAM 'PLANCK6K.BAS' SOLVES PLANCK'S EQUATION AND PLOTS ENERGY
2850 REM IN Watts/cm^2-Mu AS A FUNCTION OF WAVELENGTH FROM .3 TO 1.1 Mu.
2860 REM (PROGRAM PLANCKV2 MODIFIED FOR 6K K).  R. B. MINTON, 08/22/2004.
2870 REM ----------------------------------------------------------------
2880 H=6.6260755D-27:                     REM PLANCK CONSTANT (ERG-SEC)
2890 E=2.7182818285#:                     REM E
2900 K=1.380658D-16:                      REM BOLTZMANN CONSTANT (ERG/DEG K)
2910 T=6000#:                             REM TEMPERATURE OF EXAMPLE
2920 WME=.2897756/T:                      REM MAX EMISSION, CM-DEG K
2930 SCALE=.009994371#:                   REM SCALE FACTOR FOR Y=20 AT 9 TICK
2940 N1=2#*PI*H*CC*CC*(.000000001#):      REM NUMERATOR FOR PLANCK'S EQUATION
2950 REM DIM PBM(10),PBD(10)
2960 REM PBS DETECTIVITY AT 300 DEG. K FROM 1.0 TO 3.0 MICRONS (CM(HZ)^.5/W)
2970 REM  1.0,7.45D+10,1.25,8.33D+10,1.5,9.22D+10,1.75,1.01D+11,2.0,1.09D+11
2980 REM  2.25,1.1D+11,2.5,1.0D+11,2.75,6.9D+10,3.0,3.9D+10,3.25,1.8D+09
2990 REM FOR I=1 TO 10: READ PBM(I),PBD(I): NEXT I
3000 F1$="##.####^^^^   ##.####^^^^   ##.####^^^^"
3010 H1$="   RADIANT EMITTANCE (WATTS/CM^2-MICRON) FOR 6000 DEGREES KELVIN:"
3020 H2$="--------------------------------------------------------------------"
3030 H3$="TABLE OF WAVELENGTH VS. ENERGY        TABLE OF WAVELENGTH VS. ENERGY"
3040 H4$="(ACTUAL W/CM^2-M LISTED BELOW)        (ADJUSTED W/CM^2-M ARE PLOTED)"
3050 H5$="   MICRONS     WATTS/CM^2-Mu             MICRONS     WATTS/CM^2-Mu  "
3060 H6$="  ---------    -------------            ---------    -------------  "
3070 F2$="  ###.####     ##.######^^^^            ###.####     ##.######^^^^  "
3080 CLS: SCREEN 0,0,0: FOR I=1 TO 4: PRINT: NEXT I
3090 PRINT H1$: PRINT H2$: PRINT H3$: PRINT H4$
3100 PRINT H5$: PRINT H6$
3110 ILC=6
3120 FOR I=3 TO 11 STEP .5
3130   W=.00001#*I
3140   D1=W*W*W*W*W
3150   EE=(H*CC)/(K*W*T)
3160   D2=D1*((E^EE)-1#)
3170   MIC=10000!*W
3180   WAT1=(N1/D2)*SCALE:                REM ENERGY IN WATTS/CM^2-MICRON
3190   YFIT=.0008995:
3200   WAT2=WAT1*YFIT:                    REM SCALE NUMBERS TO FIT PLOT 0-9 !
3210   IF ILC<23 THEN GOTO 3240
3220   INPUT"    . . . . ENTER <CR> TO CONTINUE ";CR$: CLS
3230   PRINT H5$:PRINT H6$:ILC=2
3240   REM CONTINUE
3250   PRINT USING F2$;MIC;WAT1;MIC;WAT2: ILC=ILC+1
3260 NEXT I
3270 INPUT"    . . . . ENTER <CR> TO CONTINUE ";CR$
3280 REM --------------------------------------------------------------------
3290 IK=0:                                REM COUNTER FOR X-AXIS PLOT
3300 CH=8: CW=8: CM=4:                    REM CHAR. HEIGHT & WIDTH, PIXELS
3310 HSP=640-1: VSP=200-1:                REM HORIZ/VERT SIZE
3320 KEY OFF: CLS: SCREEN 2:              REM SET-UP SCREEN
3330 VIEW SCREEN (0,0)-(HSP,VSP):         REM SET UP SCREEN
3340 LB=(4*CW)+CM-1: RB=(4*CW)-CM:        REM LEFT/RIGHT BORDERS IN PIXELS
3350 TB=(1*CH): BB=(3*CH)+CH+CM:          REM TOP/BOTTOM BORDERS IN PIXELS
3360 NHP=HSP-(LB+RB): NVP=VSP-(TB+BB):    REM NO. HORIZ/VERT SPACES
3370 T1$="     Radiant "
3380 T2$="Emittance (Watts/cm^2-micron) Vs. Wavelength (nm) for T=6000 K."
3390 B1$="    |        |        |        |        |        |        |        |        | "
3400 B2$="   300      400      500      600      700      800      900      1.0      1.1"
3410 B3$="                        Wavelength (Nanometers & Microns)"
3420 T1$=T1$+T2$: LOCATE  2,1: PRINT T1$: REM LOCATE = ROW,COLUMN
3430 LOCATE 22,1: PRINT B1$
3440 LOCATE 23,1: PRINT B2$
3450 LOCATE 24,1: PRINT B3$
3460 FOR I=0 TO 18 STEP 2:                REM PRINT Y-AXIS TICKS AND LABELS
3470   IR=I+3: ICL=5: ICR=77: ICN=78: II=10-(1+(I/2))
3480   LOCATE IR,ICL:PRINT"-":LOCATE IR,ICR:PRINT"-":LOCATE IR,ICN:PRINT II
3490 NEXT I:                              REM FINISHED WITH Y-AXIS T&L
3500 LINE (LB,TB)-(HSP-RB,VSP-BB),,B:     REM DRAW A BOX
3510 PMAX=-1E+08: PMIN=1E+08: WMAX=0: WMIN=0
3520 REM SCALE DETECTIVITY TO FIT PLOT AREA
3530 REM FOR I=1 TO 10: PBD(I)=PBD(I)*.000000001305#: NEXT I
3540 REM ----------- PLOT PBS DETECTIVITY VS. WAVELENGTH (MICRONS) -----------
3550 GOTO 3660:                            REM SKIP THE PbS PLOT !!!
3560 FOR I=1 TO 10
3570   IK=IK+1:                           REM X-AXIS INDEX
3580   R=PBD(I):                          REM PBS DETECTIVITY
3590   XOFF=12:                           REM X-AXIS OFFSET (+ = RIGHT)
3600   Y=(VSP-BB)-(R):                    REM Y-VALUE IS PBS (VERTICAL)
3610   X=LB+XOFF+((IK-1)*26.8):           REM X-VALUE IS INDEX (HORIZONTAL)
3620   Y=Y:                               REM SCALE PBS TO FIT PLOT AREA
3630   IF IK=1 THEN CIRCLE (X,Y),0:       REM DRAW A DOT FIRST . . . . . .
3640   IF IK>1 THEN LINE -(X,Y):          REM . . . THEN CONNECT W/ LINES
3650 NEXT I
3660 REM CONTINUE
3670 IK=0
3680 FOR I=3 TO 11 STEP .0139:            REM LOOP ON WAVELENGTH (X 0.1 MU)
3690   IK=IK+1: R=I:                      REM INCREMENT X-AXIS
3700   W=.00001#*R
3710   D1=W*W*W*W*W
3720   EE=(H*CC)/(K*W*T)
3730   D2=D1*((E^EE)-1#)
3740   MIC=10000000#*W
3750   ERGS=(N1/D2): REM IF R>10.991 THEN LOCATE 10,30: PRINT ERGS: STOP
3760   IF ERGS>PMAX THEN PMAX=ERGS: WMAX=MIC: REM MAX ERGS/WAVE
3770   IF ERGS<PMIN THEN PMIN=ERGS: WMIN=MIC: REM MIN ERGS/WAVE
3780   ERGS=(ERGS*SCALE)*.014355:         REM SCALE ENERGY TO MAX=9 TICK
3790   Y=(VSP-BB)-(ERGS):                 REM Y-VALUE IS POWER (VERTICAL)
3800   X=LB+(IK-1):                       REM X-VALUE IS INDEX (HORIZONTAL)
3810   REM Y SHOULD=20.00 AT 9 ON Y-AXIS, AND 0 (OR MIN) AT MINIMUM <------
3820   Y=Y:                                REM SCALE POWER TO FIT PLOT AREA
3830   REM LOCATE 25,5: PRINT USING F1$;MIC;ERGS;Y: REM PRINT SOME DEBUG
3840   IF IK=1 THEN CIRCLE (X,Y),0:       REM DRAW A DOT FIRST . . . . . .
3850   IF IK>1 THEN LINE -(X,Y):          REM . . . THEN CONNECT W/ LINES
3860   REM IF I>10 THEN LINE -(X,20): STOP: REM FIND WAVELENGTH = 1.00 Mu
3870 NEXT I
3880 REM PMAX=INT(100*PMAX+.5)/100: PMIN=INT(100*PMIN+.5)/100
3890 PMAX=INT(100*PMAX+.5)/10000: PMIN=INT(100*PMIN+.5)/10000
3900 F3$="##.###^^^^": F7$=F3$+" nm"
3910 F4$="Max=": F5$="Min=": F6$=" W/cm^2-Mu @"
3920 REM LOCATE 9,12: PRINT"PbS response:"
3930 REM LOCATE 10,9: PRINT"Normalized to Y=9.0"
3940 LOCATE 16,10: PRINT"Temperature = 6,000 degrees Kelvin:"
3950 LOCATE 17,10
3960 PRINT F4$;:PRINT USING F3$;PMAX;:PRINT F6$;:PRINT USING F7$;WMAX
3970 LOCATE 18,10
3980 PRINT F5$;:PRINT USING F3$;PMIN;:PRINT F6$;:PRINT USING F7$;WMIN
3990 LOCATE 19,10
4000 PRINT"Energy scaled 8.995E-04 to fit Y = 9.00"
4010 REM LOCATE 19,10: WME=WME*10000
4020 REM PRINT"MAX EMISSION =";:PRINT USING F7$;WME
4030 LOCATE 25,1: PRINT FC$;: INPUT CR$
4040 SCREEN 0,0,0
4050 REM -----------------------------------------------------------------
4060 REM Program 'PLANCKV3.BAS' solves Planck's equation and plots energy
4070 REM in Watts/cm^2-Mu as a function of wavelength from .9 to 5.7 Mu.
4080 REM (PROGRAM PLANCK6K MODIFIED FOR VENUS).  R. B. MINTON, 08/24/2004.
4090 REM -----------------------------------------------------------------
4100 REM Scale factor used to match plot of 6K curve in "Handbook of Mili-
4110 REM tary Infrared Technology (p. 19) to max radiant emittance = 10^4.
4120 REM -----------------------------------------------------------------
4130 H=6.6260755D-27:                     REM PLANCK CONSTANT (ERG-SEC)
4140 E=2.7182818285#:                     REM E
4150 K=1.380658D-16:                      REM BOLTZMANN CONSTANT (ERG/DEG K)
4160 T=523#:                              REM TEMPERATURE OF VENUS, DEG. K
4170 WME=.2897756/T:                      REM MAX EMISSION, CM-DEG K
4180 SCALE=.009994371#:                   REM RADIANT EMITTANCE SCALE FACTOR
4190 N1=2#*PI*H*CC*CC*(.000000001#):      REM NUMERATOR FOR PLANCK'S EQUATION
4200 DIM PBM(10),PBD(10)
4210 REM PBS DETECTIVITY AT 300 DEG. K FROM 1.0 TO 3.0 MICRONS (CM(HZ)^.5/W)
4220 DATA 1.0,7.45D+10,1.25,8.33D+10,1.5,9.22D+10,1.75,1.01D+11,2.0,1.09D+11
4230 DATA 2.25,1.1D+11,2.5,1.0D+11,2.75,6.9D+10,3.0,3.9D+10,3.25,1.8D+09
4240 FOR I=1 TO 10: READ PBM(I),PBD(I): NEXT I
4250 F1$="##.####^^^^   ##.####^^^^   ##.####^^^^"
4260 REM ------------- CREATE TABLE OF ENERGY VS. WAVELENGTH ------------------
4270 H1$="   RADIANT EMITTANCE (WATTS/CM^2-MICRON) FOR VENUS (523 DEG. K.):"
4280 H2$="--------------------------------------------------------------------"
4290 H3$="TABLE OF WAVELENGTH VS. ENERGY        TABLE OF WAVELENGTH VS. ENERGY"
4300 H4$="(ACTUAL W/CM^2-M LISTED BELOW)        (ADJUSTED W/CM^2-M ARE PLOTED)"
4310 H5$="   MICRONS     WATTS/CM^2-Mu             MICRONS     WATTS/CM^2-Mu  "
4320 H6$="  ---------    -------------            ---------    -------------  "
4330 F2$="  ###.####     ##.######^^^^            ###.####     ##.######^^^^  "
4340 CLS: SCREEN 0,0,0: FOR I=1 TO 4: PRINT: NEXT I
4350 PRINT H1$: PRINT H2$: PRINT H3$: PRINT H4$
4360 PRINT H5$: PRINT H6$
4370 ILC=6:                               REM LINE COUNTER NOW AT 6
4380 FOR I=9 TO 57 STEP 3:                REM USE .1 STEP FOR MAX RESOLUTION
4390   W=.00001#*I:                       REM DECREASE WAVELENGTH TO PREVENT+
4400   D1=W*W*W*W*W:                      REM A PROGRAM BLOW-UP FROM W^5
4410   EE=(H*CC)/(K*W*T)
4420   D2=D1*((E^EE)-1#)
4430   MIC=10000!*W:                      REM WAVELENGTH NOW IN MICRONS
4440   WAT1=(N1/D2)*SCALE:                REM ENERGY IN WATTS/CM^2-MICRON
4450   YFIT=178.85:
4460   WAT2=WAT1*YFIT:                    REM SCALE NUMBERS TO FIT PLOT 0-9 !
4470   IF ILC<23 THEN GOTO 4500:           REM DISPLAY 22 LINES MAX
4480   INPUT"    . . . . ENTER <CR> TO CONTINUE ";CR$: CLS
4490   PRINT H5$:PRINT H6$:ILC=2
4500   REM CONTINUE
4510   PRINT USING F2$;MIC;WAT1;MIC;WAT2: ILC=ILC+1
4520 NEXT I
4530 INPUT"    . . . . ENTER <CR> TO CONTINUE ";CR$
4540 REM ---------------- NOW PLOT ENERGY VS. WAVELENGTH --------------------
4550 IK=0:                                REM COUNTER FOR X-AXIS PLOT
4560 CH=8: CW=8: CM=4:                    REM CHAR. HEIGHT & WIDTH, PIXELS
4570 HSP=640-1: VSP=200-1:                REM HORIZ/VERT SIZE
4580 KEY OFF: CLS: SCREEN 2:              REM SET-UP SCREEN
4590 VIEW SCREEN (0,0)-(HSP,VSP):         REM SET UP SCREEN
4600 LB=(4*CW)+CM-1: RB=(4*CW)-CM:        REM LEFT/RIGHT BORDERS IN PIXELS
4610 TB=(1*CH): BB=(3*CH)+CH+CM:          REM TOP/BOTTOM BORDERS IN PIXELS
4620 NHP=HSP-(LB+RB): NVP=VSP-(TB+BB):    REM NO. HORIZ/VERT SPACES
4630 T1$="     Radiant "
4640 T2$="Emittance (Watts/cm^2-micron) Vs. Wavelength (Mu) for T= 523 K."
4650 B1$="    |        |        |        |        |        |        |        |        | "
4660 B2$="    .9      1.5      2.1      2.7      3.3      3.9      4.5      5.1      5.7"
4670 B3$="                              Wavelength (Microns)"
4680 T1$=T1$+T2$: LOCATE  2,1: PRINT T1$: REM LOCATE = ROW,COLUMN
4690 LOCATE 22,1: PRINT B1$
4700 LOCATE 23,1: PRINT B2$
4710 LOCATE 24,1: PRINT B3$
4720 FOR I=0 TO 18 STEP 2:                REM PRINT Y-AXIS TICKS AND LABELS
4730   IR=I+3: ICL=5: ICR=77: ICN=78: II=10-(1+(I/2))
4740   LOCATE IR,ICL:PRINT"-":LOCATE IR,ICR:PRINT"-":LOCATE IR,ICN:PRINT II
4750 NEXT I:                              REM FINISHED WITH Y-AXIS T&L
4760 LINE (LB,TB)-(HSP-RB,VSP-BB),,B:     REM DRAW A BOX
4770 PMAX=-1E+08: PMIN=1E+08: WMAX=0: WMIN=0: REM FIND POWER/WLNTH MAX/MIN
4780 REM SCALE DETECTIVITY TO FIT PLOT AREA (Y=0 TO 9)
4790 FOR I=1 TO 10: PBD(I)=PBD(I)*.000000001305#: NEXT I
4800 REM ----------- PLOT PBS DETECTIVITY VS. WAVELENGTH (MICRONS) -----------
4810 REM GOTO 940:                        REM SKIP THE PbS PLOT?  REM=YES
4820 FOR I=1 TO 10
4830   IK=IK+1:                           REM X-AXIS INDEX
4840   R=PBD(I):                          REM PBS DETECTIVITY
4850   XOFF=12:                           REM X-AXIS OFFSET (+ = RIGHT)
4860   Y=(VSP-BB)-(R):                    REM Y-VALUE IS PBS (VERTICAL)
4870   X=LB+XOFF+((IK-1)*26.8):           REM X-VALUE IS INDEX (HORIZONTAL)
4880   Y=Y:                               REM SCALE PBS TO FIT PLOT AREA
4890   IF IK=1 THEN CIRCLE (X,Y),0:       REM DRAW A DOT FIRST . . . . . .+
4900   IF IK>1 THEN LINE -(X,Y):          REM . . . . THEN CONNECT W/ LINES
4910 NEXT I
4920 REM CONTINUE
4930 IK=0
4940 REM STEP LOOKS CRAZY, BUT IT PLOTS EXACTLY FROM LEFT TO RIGHT BORDERS !
4950 FOR I=9 TO 57 STEP .08341:           REM LOOP ON WAVELENGTH (X 0.1 MU)
4960   IK=IK+1: R=I:                      REM INCREMENT X-AXIS
4970   W=.00001#*R
4980   D1=W*W*W*W*W
4990   EE=(H*CC)/(K*W*T)
5000   D2=D1*((E^EE)-1#)
5010   MIC=10000#*W
5020   ERGS=(N1/D2):                      REM OLD=ERGS, NEW=RADIANT EMITT.
5030   IF ERGS>PMAX THEN PMAX=ERGS: WMAX=MIC: REM MAX ERGS/WAVE
5040   IF ERGS<PMIN THEN PMIN=ERGS: WMIN=MIC: REM MIN ERGS/WAVE
5050   ERGS=(ERGS*SCALE)*2853.1:          REM SCALE ENERGY TO MAX=9 TICK
5060   Y=(VSP-BB)-(ERGS):                 REM Y-VALUE IS POWER (VERTICAL)
5070   X=LB+(IK-1):                       REM X-VALUE IS INDEX (HORIZONTAL)
5080   REM Y SHOULD=20.00 AT 9 ON Y-AXIS, AND 0 (OR MIN) AT MINIMUM <------
5090   Y=Y: REM OLD VALUE IS Y=Y-1        REM SCALE Y=0 TO FIT PLOT AREA
5100   REM LOCATE 25,5: PRINT USING F1$;MIC;ERGS;Y: REM PRINT SOME DEBUG
5110   IF IK=1 THEN CIRCLE (X,Y),0:       REM DRAW A DOT FIRST . . . . . .
5120   IF IK>1 THEN LINE -(X,Y):          REM . . . THEN CONNECT W/ LINES
5130   REM IF I>51 THEN LINE -(X,165): STOP: REM FIND WAVELENGTH = 5.1 Mu+
5140 NEXT I:                              REM TO VERIFY CALIBRATION(REM=NO)
5150 F3$="##.###^^^^": F7$=F3$+" Mu"
5160 F4$="Max=": F5$="Min=": F6$=" W/.. @"
5170 LOCATE 9,12: PRINT"PbS response:"
5180 LOCATE 10,10: PRINT"Normalized to Y=9"
5190 LOCATE 16,40: PRINT"Temperature=523 deg. Kelvin: Venus"
5200 LOCATE 17,40
5210 PRINT F4$;:PRINT USING F3$;PMAX;:PRINT F6$;:PRINT USING F7$;WMAX
5220 LOCATE 18,40
5230 PRINT F5$;:PRINT USING F3$;PMIN;:PRINT F6$;:PRINT USING F7$;WMIN
5240 LOCATE 19,40
5250 PRINT"Energy scaled 1.787E+00 to fit Y=9"
5260 LOCATE 25,1: PRINT FC$;: INPUT CR$
5270 GOTO 520:                            REM LOOP THRU EVERYTHING AGAIN
5280 SAVE"ATOM101.BAS",A:   REM TYPE RUN (LINE #) TO SAVE TO 'C' DRIVE
5290 SAVE"A:ATOM101.BAS",A: REM TYPE RUN (LINE #) TO SAVE TO 'A' FLOPPY
5300 END