100 REM PROGRAM 'CONVRAW.BAS' CONVERTS RAW DATA FILE TO CONDENSED 6 MINUTE
110 REM DATA FILE.  DUMP LISTS 1 HR & DAILY SUMS.  R. B. MINTON 09-03-2002.
120 NV=30*24*10: DIM C(NV):           REM C-ARRAY=24HRS X 10 PER HR X 30 DAYS
130 REM READ FILE 'OUT.M__' AND CONVERT TO FILE 'OUT.RAW'
140 FIL1$="OUT.M11":                    REM INPUT FILENAME
150 FIL2$="OUT.RAW":                    REM OUTPUT FILENAME
160 OPEN FIL1$ FOR INPUT AS 3:          REM OPEN INPUT DATA FILE
170 OPEN FIL2$ FOR OUTPUT AS 4:         REM OPEN OUTPUT DATA FILE
180 N=0: HR=0: KEY OFF
190 UHR=0: DDY=6: CMO=8: LDY=31: YR$="2002: ": ID$=YR$+FIL1$
200 REM -----------------------------------------------------------------------
210 REM NOTE:  TIMES/DATES ARE MOUNTAIN STANDARD TIMES/DATES FROM COMPUTER -
220 REM        CONVERT TO UT TIMES/DATES FOR GRAPHICAL DISPLAY/INTERPRETATION.
230 REM        1 LINE OF INPUT FILE = 10 X 6 MIN = 1 HOUR PER RECORD
240 REM -----------------------------------------------------------------------
250 INPUT #3,START$,SDATE$,STIME$,UN$: REM MULTIMETER UNITS = MEGA-OHMS
260 DUMP$=" ": DUMP$="P":              REM PRINT TABLE TO SCREEN IF DUMP = P
270 F1$="DATA DUMP FOR 1/10 HOUR COUNTS IN RAW INPUT FILE:  &"
280 F2$="NOTE: '1 HR SUM' IS THE SUM FROM START OF HOUR TO END OF THE HOUR"
290 F3$="ALSO: '24 HR SUM' IS THE SUM FROM 0H UT TO END OF CURRENT HOUR UT"
300 F4$="UNIVERSAL TIME  <---- 1/10 HOUR (6 MINUTE) COUNTS ---->   1HR    24HR"
310 F5$="MONTH  DAY  HR   .1  .2  .3  .4  .5  .6  .7  .8  .9  1.   SUM     SUM"
320 F6$="-----  ---  --  --- --- --- --- --- --- --- --- --- ---   ---   -----"
330 F7$="   ##   ##  ##  ### ### ### ### ### ### ### ### ### ###  ####   #####"
340 IF DUMP$<>"P" THEN GOTO 370
350 CLS: PRINT USING F1$;ID$
360 PRINT F2$: PRINT F3$: PRINT: PRINT F4$: PRINT F5$: PRINT F6$
370 REM CONTINUE
380 HR=HR+1:                           REM 10 OBSERVATION INTERVALS
390 FOR II=1 TO 10
400   IF EOF (3) THEN GOTO 650
410   INPUT #3,DAT$,TIM$,FTY$
420   INPUT #3,V1,V2,V3,V4,V5,V6,V7,V8,V9,V10
430   IF II=1 THEN C(N+1)=V1: H1=V1
440   IF II<10 THEN GOTO 490
450   C(N+2)=V2: C(N+3)=V3: C(N+4)=V4: C(N+5)=V5: C(N+6)=V6
460   C(N+7)=V7: C(N+8)=V8: C(N+9)=V9: C(N+10)=V10
470   HNV=H1+V2+V3+V4+V5+V6+V7+V8+V9+V10:      REM HOURLY SUM
480   DNV=DNV+HNV:                             REM DAILY SUM
490   REM CONTINUE
500 NEXT II
510 N=N+10
520 IF DUMP$<>"P" THEN GOTO 610
530   PRINT USING F7$;CMO;DDY;UHR;H1;V2;V3;V4;V5;V6;V7;V8;V9;V10;HNV;DNV
540   UHR=UHR+1
550   IF UHR<>24 THEN GOTO 590
560   UHR=0: DDY=DDY+1: DNV=0
570 IF DDY>LDY THEN DDY=1: CMO=CMO+1: ID$=YR$+FIL1$
580   PRINT: PRINT F4$: PRINT F5$: PRINT F6$
590   REM CONTINUE
600   REM FOR KK=1 TO 50: NEXT KK
610 REM CONTINUE
620 WRITE #4,DAT$;TIM$;FTY$
630 WRITE #4,H1;V2;V3;V4;V5;V6;V7;V8;V9;V10
640 GOTO 370:                                 REM READ FILE UNTIL 'EOF'
650 REM CONTINUE ----- ERROR TRAP FOR END-OF-FILE 'EOF' ON INPUT FILE #3 -----
660 CLOSE #3: CLOSE #4
670 END